WAIT

Omschrijving:
Dit eenvoudige statement zorgt ervoor dat de uitvoering van het programma stopt en wacht 
op de gebruikersinput events. Wanneer de gebruiker een interactie met een venster 
of andere control aangaat en die control of dat venster wordt door het programma beheerd 
dan ontstaat er een event. Het programma hervat de uitvoering bij de event handler 
die voor die interactie is toegewezen.

Gebruik:

  'demonstrate the wait command (in three places)
  nomainwin
  open "Geometric wite-board" for graphics_nsb as #geo
  print #geo, "trapclose [quit]"
  print #geo, "when rightButtonUp [popupMenu]"

  wait  ' stop and wait for a menu item to be chosen

[popupMenu]
  popupmenu "&Square Spiral", [asSquare], "&Triangular Spiral", [asTriangle]
  wait

[asSquare]
  print #geo, "cls ; home ; down ; color red"
  for x = 1 to 120
    print #geo, "go "; x; " ; turn 87"
  next x
  wait

[asTriangle]
  print #geo, "cls ; home ; down ; color blue"
  for x = 1 to 120
    print #geo, "go "; x; " ; turn 117"
  next x
  wait

[quit]
  close #geo
  end

Noteer: Over het algemeen, moedigt Liberty BASIC het gebruik van WAIT aan 
in plaats van  de vroegere praktijk waarbij input werd toegepast.