CHECKBOX

CHECKBOX #handle.ext, "label", setHandler, resetHandler, x, y, wide, high

Omschrijving:

Hiermee voegt u een checkbox control met referentie #handle.ext toe aan een venster.
Checkbox kent twee standen, set en reset.
Zij zijn nuttig om input van het on/off informatie type te vergaren.

Hier is een beschrijving van de parameters van het CHECKBOX statement:

#handle.ext
Deze parameter specificeert de handle voor deze control.
Het #handle deel zou het zelfde moeten zijn als de handle van het venster dat
de checkbox bevat, en het .ext deel is het unieke naam deel van de checkbox in het venster.

"label"
Deze parameter bevat de zichtbare tekst op de checkbox

setHandler
Dit is het de aftak etiket [label] of subroutine om naar te springen als de gebruiker
de checkbox set door erop te klikken. Wanneer de checkbox in de "set" stand is,
verschijnt er een vinkje als controleteken.
Zie ook: Controls and Events

resetHandler
Dit is het de aftak etiket [label] of subroutine om naar te springen als de gebruiker
de checkbox reset door erop te klikken. Wanneer de checkbox in de "reset" stand is,
verdwijnt het vinkje.
Zie ook: Controls and Events

x
Dit is de x-positie van de checkbox met betrekking tot de linker bovenhoek van het venster
waartoe het behoort.

y
Dit is de y-positie van de checkbox met betrekking tot de linker bovenhoek van het venster
waartoe het behoort.

width
Dit is de breedte van de checkbox control.

high
Dit is de hoogte van de checkbox control.

 

Checkbox Commando's:
Checkbox kent de volgende commando's:

#handle.ext "set"
Hiermee "set" men de checkbox, waardoor een controleteken erin verschijnt

#handle.ext "reset"
Hiermee "reset" men de checkbox, waardoor het vinkje verdwijnt.

#handle.ext "value? result$"
De variabele result$ wordt geladen met de status ( "set" of "reset") van de checkbox.

#handle.ext "setfocus"
Met dit commando kunnen we de checkbox selecteren.
Dit betekent dat elke toets indruk naar die checkbox zal worden geleid.

#handle.ext "locate x y width height"
Dit commando verplaatst de checkbox binnen het venster. Dit werkt slechts als de checkbox
in een gewoon window type venster wordt geplaatst. De checkbox zal qua grootte niet
worden bijgewerkt en ook voor wat betreft de plaats niet worden bijgewerkt
voordat er een opdracht voor het verversen (REFRESH) wordt verzonden naar het venster.
Zie het RESIZE.BAS- voorbeeldprogramma.

#handle.ext "font facename pointSize"
Deze opdracht verandert het lettertype van de checkbox in het gespecificeerde lettertype en lettergrootte.
Als de exact gevraagde lettertype en bijbehorende gevraagde lettergrootte niet aanwezig zijn,
dan zal Liberty BASIC proberen om een zo dichtmogelijk gelijkende lettertype en grootte te vinden,
waarbij grootte de voorkeur heeft boven soort.
Voorbeeld:
#handle.ext "font times_new_roman 10"

 

#handle.ext" enable "
Dit zorgt ervoor dat er toegang tot de control is.

#handle.ext " disable"
Dit maakt de control inactief , de knop wordt licht grijs.

#handle.ext " show"
Dit zorgt er voor dat de control zichtbaar wordt.

#handle.ext " hide"
Dit verbergt de control en maakt het onzichtbaar.

For information on creating controls with different background colors,
see Colors and the Graphical User Interface.

 

Gebruik

Here are sample programs that use checkboxes.

' This code demonstrates how to use checkboxes in
' Liberty BASIC programs with branch label handlers

nomainwin
button #1, "&Ok", [quit], UL, 120, 90, 40, 25
checkbox #1.cb, "I am a checkbox", [set], [reset], 10, 10, 130, 20
button #1, "Set", [set], UL, 10, 50
button #1, "Reset", [reset], UL, 50, 50
textbox #1.text, 10, 90, 100, 24

WindowWidth = 180
WindowHeight = 160

open "Checkbox test" for dialog as #1
#1 "trapclose [quit]"
[inputLoop]
input r$

[set]
#1.cb "set"
goto [readCb]

[reset]
#1.cb "reset"
goto [readCb]
end

[readCb]
#1.cb "value?"
input #1.cb, t$
#1.text "I am "; t$
goto [inputLoop]

[quit] close #1 : end

 

' This code demonstrates how to use checkboxes in
' Liberty BASIC programs with subroutine handlers

nomainwin
button #1, "&Ok", [quit], UL, 120, 90, 40, 25
checkbox #1.cb, "I am a checkbox", checkSet, checkReSet, 10, 10, 130, 20
textbox #1.text, 10, 90, 100, 24

WindowWidth = 180
WindowHeight = 160
open "Checkbox test" for dialog as #1
#1 "trapclose [quit]"

[inputLoop]
wait

sub checkSet cbHandle$
#cbHandle$ "value? v$"
#1.text "I am ";v$
end Sub

sub checkReSet cbHandle$

#cbHandle$ "value? v$"

#1.text "I am ";v$
end Sub

[quit] close #1 : end